Wolfram Blog
Jeffrey Bryant

2020’s Winter Solstice Hosts the Greatest Conjunction in Nearly Four Hundred Years

December 17, 2020 — Jeffrey Bryant, Research Programmer, Wolfram|Alpha Scientific Content

On December 21, 2020, a visual astronomical spectacle will occur. The planets Jupiter and Saturn will pass so close to each other in the sky that, to the unaided eye, they will be difficult to separate. This is the closest the two planets have come in 397 years; the last time they were this close was July 16, 1623. When Jupiter and Saturn come close to each other in the sky as seen from Earth, this is known as a “great conjunction” and happens about every 20 years or so. But not all great conjunctions are as close as this one. The next great conjunction will be on November 5, 2040, and again on April 10, 2060, but the planets will be a bit over a degree apart, so not as close as the 2020 event. The next comparable event will be on March 15, 2080.

First, it’s worth mentioning that this event is being referred to as a “Christmas Star” in the media and across popular culture. This Christmas Star, or “Star of Bethlehem,” is not scientifically connected to the forthcoming conjunction, except that it happens near Christmas Day. There are a number of possible reasons as to what might have been observed by the Magi in the Christmas Story over two thousand years ago, which include comets, supernovae or other events. One of the possible explanations that might have some relevance to this post is to note that magi were likely Zoroastrians, known to use the stars and planets to divine meaning via astrology. As such, they would often use the positions of the planets, especially conjunctions involving them, as signs of something significant. It may have been a planetary conjunction in a constellation important to astrology. It’s hard to know what scientific explanation the Star of Bethlehem actually had since no written detailed explanation of the observation exists. But having a close planetary conjunction in our skies so close to Christmas makes for a popular and heartwarming reference.

Leading Up to the Conjunction

I’ll make use of several Wolfram Function Repository items to explore the 2020 event. The following view is a wide‐field view computed about six days before the event. Due to the point size used in the graphic to represent brightness, the planets look larger than they actually are, but the graphic still allows the two objects to be seen as distinct. This view doesn’t show the horizon (which would be tilted here) but uses SkyPositionChart to center on specific sky coordinates where the conjunction takes place, oriented within the celestial sphere with north up. The brown line is the ecliptic plane, the mean path the Sun and planets appear to follow through the course of the year.

ResourceFunction
&#10005

ResourceFunction["SkyPositionChart"][<|
  "RightAscension" -> Quantity[20.178, "HoursOfRightAscension"],
  "Declination" -> Quantity[-20.5372, "AngularDegrees"]|>,
 DateObject[{2020, 12, 15, 18, 0}, TimeZone -> "America/Chicago"],
 "ShowEntityLabel" -> False, "EntityRadius" -> .004,
 "IncludeMoon" -> False, "IncludeSun" -> False,
 "EntityColor" -> Opacity[0]]

On December 16, 2020, a few days before the conjunction, the thin crescent Moon was positioned near the two planets, just above the horizon, making for a very picturesque scene. As before, the brown line is the ecliptic plane (not the horizon).

ResourceFunction
&#10005

ResourceFunction["SkyPositionChart"][<|
  "RightAscension" -> Quantity[20.178, "HoursOfRightAscension"],
  "Declination" -> Quantity[-20.5372, "AngularDegrees"]|>,
 DateObject[{2020, 12, 16, 18, 0}, TimeZone -> "America/Chicago"],
 "ShowEntityLabel" -> False, "EntityRadius" -> .004,
 "IncludeSun" -> False, "EntityColor" -> Opacity[0]]

For an all-sky view, I used SkyChart to see where in the sky the event took place, including the horizon. As can be seen, the two planets were low in the southwest around 6pm local time. The Moon was high in the south and Mars high in the south-southeast, just east of the Moon.

ResourceFunction
&#10005

ResourceFunction["SkyChart"][{Entity["Planet", "Jupiter"],
  Entity["Planet", "Saturn"]}, GeoPosition[{40.11, -88.22}],
 DateObject[{2020, 12, 21, 18, 0}, TimeZone -> "America/Chicago"]]

Angular Separation

To quantify the observations a bit, it’s useful to clarify what is meant by “angular distance.” After all, on December 21, 2020, the actual distance between Jupiter and Saturn won’t be all that close. They are nearly five astronomical units (AU) apart.

ResourceFunction
&#10005

ResourceFunction["AstroDistance"][{Entity["Planet", "Jupiter"],
  Entity["Planet", "Saturn"]}, DateObject[{2020, 12, 21}]]

Angular distance is the apparent distance between two objects in the sky as seen from the observers’ points of view against the celestial sphere. If two objects are on opposite sides of the sky, they have an angular separation of 180°. I used AstroAngularDistance to compute the angular distance in the sky between Jupiter and Saturn throughout the month of December.

ts = ResourceFunction
&#10005

ts = ResourceFunction["AstroAngularDistance"][
  Entity["Planet", "Jupiter"], Entity["Planet", "Saturn"],
  DateRange[DateObject[{2020, 12, 1}], DateObject[{2020, 12, 31}]]]

The resulting TimeSeries was then plotted to show that the two planets will pass within about 0.1° of each other.

DateListPlot
&#10005

DateListPlot[ts, FrameLabel -> {None, "Angular Separation (degrees)"}]

If you aren’t used to thinking in terms of angular separation, a good rule of thumb is to use the width of your little finger at arm’s length to estimate the width of 1° against the sky. On December 12, Jupiter and Saturn appeared about one index-finger width apart. Obviously “index-finger widths” are not standard units, but it’s a useful tool to use in the field when estimating angular separation. Your three middle fingers span about 5° at arm’s length; your closed fist is about 10°; and an outstretched hand is about 25°. So, on December 21, 2020, Jupiter and Saturn will be about 1/10 of a finger width at arm’s length apart.

Something to keep in mind is that although the two planets will be very close, the separation from the Sun is also important for observing such an event. If this event happens when the planets are close to the Sun in the sky, it will happen during the day and be very difficult to observe. So, how far will the planets be from the Sun for this event? I used AstroAngularDistance again to find out.

ResourceFunction
&#10005

ResourceFunction["AstroAngularDistance"][Entity["Planet", "Jupiter"],
 Entity["Star", "Sun"], DateObject[{2020, 12, 21}]]

Now, 30° isn’t a huge separation angle, which is why the event needs to be observed shortly after sunset. Viewed too early, the Sun will still be up; too late, and the planets themselves will set. Compare this to the separation angle for the great conjunction 397 years ago.

ResourceFunction
&#10005

ResourceFunction["AstroAngularDistance"][Entity["Planet", "Jupiter"],
 Entity["Star", "Sun"], DateObject[{1623, 7, 16}]]

So the separation distance between the planets and the Sun was only about 13° in 1623. This made the event far more difficult to observe, as the planets would have been very low on the horizon after sunset against a significantly bright sky. When researching this event online, I found several claims that the 1623 event went “unobserved.” Combine the small angular distance from the Sun and the fact that telescopes were a relatively new tool for studying astronomical events, and it’s no surprise that few records of the 1623 event can be found.

Solar System Configuration

To better understand the arrangement of the solar system during this event, I used SolarSystemPlot3D to highlight the positions of Earth, Jupiter and Saturn and draw lines connecting them to simulate the angle between them. To better show how the angular distance closes, results for both November 1, 2020, and December 21, 2020, are shown.

nov1 = ResourceFunction
&#10005

nov1 = ResourceFunction["SolarSystemPlot3D"][{Red,
    Sphere[Entity["Planet", "Earth"], .25],
    Sphere[Entity["Planet", "Jupiter"], .25],
    Sphere[Entity["Planet", "Saturn"], .25],
    Line[{{Entity["Planet", "Earth"],
       Entity["Planet", "Jupiter"]}, {Entity["Planet", "Earth"],
       Entity["Planet", "Saturn"]}}]},
   DateObject[{2020, 11, 1, 18, 0}, TimeZone -> "America/Chicago"],
   PlotRange -> 10, ViewPoint -> Above, Boxed -> False,
   ViewAngle -> Pi/6, ImageSize -> 250];

dec21 = ResourceFunction
&#10005

dec21 = ResourceFunction["SolarSystemPlot3D"][{Red,
    Sphere[Entity["Planet", "Earth"], .25],
    Sphere[Entity["Planet", "Jupiter"], .25],
    Sphere[Entity["Planet", "Saturn"], .25],
    Line[{{Entity["Planet", "Earth"],
       Entity["Planet", "Jupiter"]}, {Entity["Planet", "Earth"],
       Entity["Planet", "Saturn"]}}]},
   DateObject[{2020, 12, 21, 18, 0}, TimeZone -> "America/Chicago"],
   PlotRange -> 10, ViewPoint -> Above, Boxed -> False,
   ViewAngle -> Pi/6, ImageSize -> 250];

On November 1, as seen from Earth, Jupiter and Saturn are separated by a small angle. But on December 21, this angle becomes negligible. During this interval of time, Jupiter and Saturn move very little due to their distant orbits. Earth has most of the motion, resulting in the separation angle nearly vanishing.

Grid
&#10005

Grid[{{nov1, dec21}}]

If you look at the arrangement during the 1623 event, Jupiter and Saturn were both on the same side of the solar system, while Earth was on the opposite side, but the line drawn through Earth, Jupiter and Saturn passes much closer to the Sun.

ResourceFunction
&#10005

ResourceFunction["SolarSystemPlot3D"][{Red,
  Sphere[Entity["Planet", "Earth"], .25],
  Sphere[Entity["Planet", "Jupiter"], .25],
  Sphere[Entity["Planet", "Saturn"], .25],
  Line[{{Entity["Planet", "Earth"],
     Entity["Planet", "Jupiter"]}, {Entity["Planet", "Earth"],
     Entity["Planet", "Saturn"]}}]},
 DateObject[{1623, 7, 16}, TimeZone -> "America/Chicago"],
 PlotRange -> 10, ViewPoint -> Above, Boxed -> False,
 ViewAngle -> Pi/6, ImageSize -> 300]

Animations

Because our usual Gregorian calendar system switches months during the period of interest, it’s tricky to create a smooth time iteration from start to end using Gregorian dates. It’s easier to use the Julian date, which counts days since the beginning of year –4713 using a floating-point number. I created animations from the beginning of November through the month of December in one-day increments.

start = JulianDate
&#10005

start = JulianDate[
   DateObject[{2020, 11, 1, 18, 0}, TimeZone -> "America/Chicago"]];

end = JulianDate
&#10005

end = JulianDate[
   DateObject[{2020, 12, 31, 18, 0}, TimeZone -> "America/Chicago"]];

Here is the construction of frames showing the progression of the celestial sphere variant.

frames1 = Table
&#10005

frames1 =
  Table[ResourceFunction["SkyPositionChart"][<|
     "RightAscension" -> Quantity[20.178, "HoursOfRightAscension"],
     "Declination" -> Quantity[-20.5372, "AngularDegrees"]|>,
    FromJulianDate[d], "ShowEntityLabel" -> False,
    "EntityRadius" -> .004, "IncludeMoon" -> False,
    "IncludeSun" -> False, "EntityColor" -> Opacity[0]], {d, start,
    end, 1}];

&#10005

ListAnimate[frames1]

(The result can also be seen on YouTube here.)

Here is the construction of frames showing the progression of the all-sky variant as seen from Champaign, Illinois, USA.

frames2 = Table
&#10005

frames2 =
  Table[Rasterize[
    ResourceFunction["SkyChart"][{Entity["Planet", "Jupiter"],
      Entity["Planet", "Saturn"]}, GeoPosition[{40.11, -88.22}],
     FromJulianDate[d]]], {d, start, end, 1}];

ListAnimate
&#10005

ListAnimate[frames2]

(The result can also be seen on YouTube here.)

Wrapping Up 2020 with Individual Observations

It has been an interesting year full of all manner of events, including a naked‐eye comet. As 2020 draws to a close, it seems we will get one more spectacle to add to this year’s list of happenings. Of course, while large public observing sessions are discouraged due to the pandemic, you can use the Wolfram Language to explore the event on your computer, share the results with others online and bring attention to such events to encourage individual observations.

Read more about this rare occurrence and add your own observations on Wolfram Community.

Leave a Comment

One Comment


Morton Goldberg

Very interesting post. I learned a lot from it.

Posted by Morton Goldberg    December 22, 2020 at 4:58 am


Leave a comment